*Program 16-6 Creating a summary data set using PROC MEANS;
proc means data=learn.blood noprint;
   var RBC WBC;
   output out = my_summary
          mean = MeanRBC MeanWBC;
run;

title "Listing of MY_SUMMARY";
proc print data=my_summary noobs;
run;

*Program 16-7 Outputting more than one statistics with PROC MEANS;
proc means data=learn.blood noprint;
   var RBC WBC;
   output out = many_stats
          mean     = M_RBC M_WBC
          n        = N_RBC N_WBC
          nmiss    = Miss_RBC Miss_WBC
          median   = Med_RBC Med_WBC;
run;

*Program 16-8 Demonstrating the OUTPUT option AUTONAME;
proc means data=learn.blood noprint;
   var RBC WBC;
   output out = many_stats
          mean     =
          n        =
          nmiss    =
          median   = / autoname;
run;

*Program 16-9 Adding a BY statement to PROC MEANS;
proc sort data=learn.blood out=blood;
   by Gender;
run;

proc means data=blood noprint;
   by Gender;
   var RBC WBC;
   output out = by_gender
          mean = MeanRBC MeanWBC
          n    = N_RBC N_WBC;
run;

*Program 16-10 Adding a CLASS statement to PROC MEANS;
proc means data=blood noprint;
   class Gender;
   var RBC WBC;
   output out = with_class
          mean = MeanRBC MeanWBC
          n    = N_RBC N_WBC;
run;

*Program 16-11 Adding the NWAY option to PROC MEANS;
proc means data=blood noprint nway;
   class Gender;
   var RBC WBC;
   output out = with_class
          mean = MeanRBC MeanWBC
          n    = N_RBC N_WBC;
run;

*Program 16-12 Using two CLASS variables with PROC MEANS;
proc means data=learn.blood noprint;
   class Gender AgeGroup;
   var RBC WBC;
   output out = summary
          mean =
          n = / autoname;
run;