Handout09 Stat3900/4950

------------------------------------------------------------------------------

DM 'LOG;CLEAR;OUT;CLEAR';
OPTIONS PAGENO = 1 LINESIZE = 74 PAGESIZE = 64;

* When anthropologists analyze human skeletal remains,
an important piece of information is living stature (the
height of the person when alive).  Since skeletons are
usually quite incomplete, inferences about stature are
commonly based on statistical methods that utilize
measurements on small bones.  The paper "The Estimation
of Adult Stature from Metacorpal Bone Length" (Amer. J.
of Phys Antro. (1978): 113-120) presented data to
validate one such method.  Consider the accompanying
representative data, where
x = metacorpal bone I length (cm)
y = stature (cm).;

DATA HT;
  INPUT METALEN STATURE;

DATALINES;
45 171
51 178
39 157
41 163
52 183
48 172
49 183
46 172
43 175
47 173
;

* SOME DESCRIPTIVE STATISTICS.;

PROC PRINT DATA = HT;
  TITLE 'HEIGHTS DATA';
  VAR STATURE METALEN;
RUN;

PROC MEANS DATA = HT;
  VAR STATURE METALEN;
RUN;

PROC UNIVARIATE DATA = HT;
  VAR STATURE METALEN;
RUN;

* PLOT THE DATA.;

PROC PLOT DATA=HT;
  PLOT STATURE*METALEN;
RUN;

PROC GPLOT DATA=HT;
  PLOT STATURE*METALEN;
RUN;

* CORRELATION;

PROC CORR DATA=HT;
  TITLE 'CORRELATION BETWEEN METALEN AND STATURE';
  VAR STATURE METALEN;
RUN;

* REGRESSION AND PLOT WITH THE PREDICTED VALUES.;

PROC REG DATA=HT;
  TITLE 'REGRESSION OF STATURE ON METALEN';
  MODEL STATURE = METALEN;
  PLOT PREDICTED. *METALEN = 'P' STATURE*METALEN='*' / OVERLAY;
RUN;

* MAKE A PLOT WITH THE REGRESSION LINE ON IT.;

SYMBOL1
  VALUE=DIAMOND
  HEIGHT=2
  INTERPOL=R
  COLOR=BLACK
;

TITLE 'PLOT WITH REGRESSION LINE ON IT.';

PROC GPLOT DATA=HT;
  PLOT STATURE*METALEN;
RUN;