Handout08 Stat3900/4950

Cody& Smith page 163

------------------------------------------------------------------------------

* Ch7, Program c;

DM 'LOG;CLEAR;OUT;CLEAR';
OPTIONS PAGENO = 1 LINESIZE = 74 PAGESIZE = 64;

DATA RITALIN;
  DO GROUP = 'NORMAL', 'HYPER';
    DO DRUG = 'PLACEBO', 'RITALIN';
      DO SUBJ = 1 TO 4;
        INPUT ACTIVITY @;
        OUTPUT;
      END;
    END;
  END;

DATALINES;
50 45 55 52  67 60 58 65  70 72 68 75  51 57 48 55
;

* Run the two-way ANOVA with interaction;

PROC ANOVA DATA=RITALIN;
  TITLE 'Analysis of Activity study';
  CLASS GROUP DRUG;
  MODEL ACTIVITY = GROUP | DRUG;
  MEANS GROUP | DRUG;
RUN;

* Make the interaction plot;

PROC MEANS DATA=RITALIN NWAY NOPRINT;
  CLASS GROUP DRUG;
  VAR ACTIVITY;
  OUTPUT OUT=MEANS MEAN=;
RUN;

SYMBOL1
  VALUE=DOT
  INTERPOL=JOIN
  LINE=1
  COLOR=BLACK
;

SYMBOL2
  VALUE=DIAMOND
  INTERPOL=JOIN
  LINE=2
  COLOR=RED
;

PROC GPLOT DATA=MEANS;
  PLOT ACTIVITY*DRUG=GROUP;
RUN;

* Compute the simple contrasts for each group within drug;

PROC GLM DATA=RITALIN;
  TITLE 'Analysis of Activity study - Planned Comparisons';
  CLASS GROUP drug;
  MODEL ACTIVITY = GROUP | DRUG;
  CONTRAST 'Hyperactivity only' DRUG 1 -1
                                GROUP*DRUG 1 -1 0 0;
  CONTRAST 'Normal only' DRUG 1 -1
                         GROUP*DRUG 0 0 1 -1;
RUN;

------------------------------------------------------------------------------